Sut i dynnu sylw at e-byst yn awtomatig yn seiliedig ar atodiad penodol mewn rhagolwg?

Wrth dderbyn rhai e-byst sydd ag atodiad pwysig penodol, efallai y bydd angen i chi eu tynnu allan, fel y gallwch ddod o hyd iddynt yn gyflym ac yn hawdd i'w llifo i fyny. Yr erthygl hon, byddaf yn siarad am ffordd hawdd o dynnu sylw awtomatig at yr e-byst sy'n atodi gydag enwau penodol.

Fflagiwch e-byst yn awtomatig yn seiliedig ar ymlyniad penodol â chod VBA

Fflagiwch e-byst yn awtomatig yn seiliedig ar ymlyniad penodol â chod VBA

I dynnu sylw at yr e-byst sy'n cynnwys yr atodiad penodol, cymhwyswch y cod VBA canlynol:

1. Lansio'r Rhagolwg, ac yna dal i lawr y ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch ddwywaith SesiwnOutlook oddi wrth y Prosiect1 (VbaProject.OTM) cwarel i agor modd newydd, ac yna copïo a gludo'r cod canlynol i'r modiwl gwag.

Cod VBA: Auto yn fflagio'r e-byst yn seiliedig ar atodiad penodol:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Nodyn: Yn y cod uchod, gallwch newid estyniad y ffeil ac enw'r ffeil atodi i'ch angen.

3. Yna cadwch y cod, ac ailgychwynwch yr Outlook i sicrhau bod y cod yn dod i rym, nawr, wrth dderbyn yr e-byst y mae enwau atodiadau yn cynnwys y testun penodedig, bydd Outlook yn tynnu sylw at yr e-bost hwn yn awtomatig ar gyfer gwaith dilynol, gweler y screenshot: