Sut i argraffu tasgau yn seiliedig ar gategori yn Outlook?

Gan dybio, mae yna amrywiol gategorïau lliw yn eich tasgau Outlook, ac nawr, rydych chi am argraffu'r rhestrau o dasgau yn seiliedig ar y categorïau mewn gwahanol dudalennau. Sut allech chi ddatrys y swydd hon yn Outlook?

Argraffu tasgau yn seiliedig ar gategorïau mewn gwahanol dudalennau â llaw fesul un

Argraffu tasgau yn seiliedig ar gategorïau mewn gwahanol dudalennau gyda chod VBA

Argraffu tasgau yn seiliedig ar gategorïau mewn gwahanol dudalennau â llaw fesul un

Yn Outlook, gallwch argraffu'r tasgau â llaw yn seiliedig ar y gwahanol gategorïau mewn gwahanol dudalennau fesul un, gwnewch fel hyn:

1. Lansiwch yr Outlook, ac ewch i'r cwarel Tasg a dewiswch y ffolder tasg rydych chi am ei hargraffu, ac yna pwyswch Ctrl + E i actifadu'r Chwilio blwch, ac yna o dan y Chwilio tab, cliciwch Categoreiddio eicon, a dewis un categori lliw y mae angen i chi ei argraffu, gweler y screenshot:

tasgau argraffu doc yn ôl categori 1

2. Ac yna, mae'r holl dasgau gyda'r categori lliw penodol wedi'u rhestru ar unwaith, gweler y screenshot:

tasgau argraffu doc yn ôl categori 2

3. Yna, ewch ymlaen i glicio Ffeil > print i argraffu'r rhestr dasgau hon fel y screenshot canlynol a ddangosir:

tasgau argraffu doc yn ôl categori 3

4. Ailadroddwch y camau uchod i argraffu'r rhestrau o dasgau gyda'r categorïau lliw eraill fesul un â llaw.

Argraffu tasgau yn seiliedig ar gategorïau mewn gwahanol dudalennau gyda chod VBA

Dyma god VBA a all eich helpu i argraffu'r tasgau yn seiliedig ar y categori mewn gwahanol dudalennau ar unwaith, gwnewch y camau canlynol:

1. Ewch i'r Gorchwyl cwarel a dewiswch y ffolder tasg rydych chi am ei hargraffu.

2. Yna, dal i lawr y ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

3. Ac yna, cliciwch Mewnosod > Modiwlau, copïo a gludo islaw'r cod i'r modiwl gwag agored:

Cod VBA: Argraffu tasgau yn seiliedig ar gategorïau mewn gwahanol dudalennau:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Yna cliciwch offer > Cyfeiriadau yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, yn y popped allan Cyfeiriadau-Prosiect1 blwch deialog, gwirio Llyfrgell Gwrthrychau Microsoft Excel ac Amser Rhedeg Sgriptio Microsoft opsiynau o'r Cyfeiriadau sydd ar Gael blwch rhestr, gweler y screenshot:

tasgau argraffu doc yn ôl categori 4

5. Ac yna, cliciwch OK botwm, nawr, pwyswch F5 yn allweddol i redeg y cod hwn, ar ôl gorffen y cod, bydd y rhestrau o dasgau â gwahanol gategorïau yn cael eu hargraffu mewn gwahanol dudalennau.