Sut i ymateb fel arfer mewn ffolder eitemau a anfonwyd gan Outlook?

Fel rheol, pan fyddwch chi'n clicio Ateb nodwedd yn ffolder eitemau a Anfonwyd ar gyfer anfon neges ychwanegol arall ar gyfer y bobl rydych chi wedi'u hanfon, bydd eich cyfeiriad e-bost eich hun yn cael ei arddangos yn y maes To fel y dangosir y screenshot canlynol. Gall hyn beri ichi newid y cyfeiriad bob tro. Sut gallai wneud i'r Camre ddefnyddio cyfeiriad gwreiddiol y derbynnydd, nid eich un chi?

anfonodd doc ateb e-byst 1

Atebwch fel arfer yn ffolder Eitemau Anfonedig o Outlook gyda nodwedd Reply All

Ymateb fel arfer mewn ffolder Eitemau Anfonedig o Outlook gyda chod VBA

Atebwch fel arfer yn ffolder Eitemau Anfonedig o Outlook gyda nodwedd Reply All

Yn Outlook, mae'r Ateb i Bawb gall nodwedd eich helpu chi i ddatrys y broblem hon, gwnewch fel hyn:

Pan fydd angen i chi ateb yr e-bost a anfonwyd i'w anfon eto i gadw cyfeiriad y derbynnydd gwreiddiol, cliciwch Ateb i Bawb botwm, ac mae cyfeiriad gwreiddiol y derbynnydd wedi'i leoli yn y I maes fel y dangosir y screenshot canlynol:

anfonodd doc ateb e-byst 2

Ymateb fel arfer mewn ffolder Eitemau Anfonedig o Outlook gyda chod VBA

Rywbryd, efallai y byddwch chi'n anghofio'r Ateb i Bawb nodwedd wrth ateb y neges a anfonwyd, felly gall y cod VBA isod eich helpu i ymateb fel arfer yn ffolder Eitemau Anfonedig trwy ddefnyddio'r nodwedd Ateb. Gwnewch gyda'r camau canlynol:

1. Daliwch i lawr y ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch ddwywaith SesiwnOutlook oddi wrth y Prosiect1 (VbaProject.OTM) cwarel i agor y modd, ac yna copïo a gludo'r cod canlynol i'r modiwl gwag.

Cod VBA: Ymateb fel arfer yn y ffolder Eitemau Anfonedig o Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

anfonodd doc ateb e-byst 3

3. Yna, arbedwch y cod, ac ailgychwynwch yr Outlook i gael yr effaith cod, nawr, wrth glicio ateb i ail-anfon e-bost i mewn Eitemau wedi'u hanfon ffolder, mae cyfeiriad y derbynnydd gwreiddiol yn cael ei arddangos yn y maes To yn ôl yr angen.