Sut i gadw categori wrth ateb neu anfon e-bost yn Outlook?

Fel rheol, pan fyddwch chi'n ateb neu'n anfon e-bost yr wyf wedi'i gategoreiddio, bydd y categori'n cael ei dynnu'n awtomatig ar yr e-bost a anfonwyd. Os ydych chi am gadw'r categori ar e-byst sy'n mynd allan wrth ateb neu anfon ymlaen, bydd yr erthygl hon yn cyflwyno dull i ddelio ag ef.

Cadwch y categori wrth ateb neu anfon e-bost gyda chod VBA

Cadwch y categori wrth ateb neu anfon e-bost gyda chod VBA

1. Dal i lawr y ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch ddwywaith SesiwnOutlook oddi wrth y Prosiect1 (VbaProject.OTM) cwarel i agor y modd, ac yna copïo a gludo'r cod canlynol i'r modiwl gwag.

Cod VBA: Cadwch y categori wrth ateb neu anfon e-bost:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

doc cadw ateb categori 1

3. Yna cadwch a chau'r ffenestr god hon, cau ac ailgychwyn yr Outlook, nawr, pan fyddwch chi'n ateb neu'n anfon e-bost gyda chategori, bydd y categori'n cael ei gadw yn y neges sy'n mynd allan Eitemau wedi'u hanfon, gweler y screenshot:

doc cadw ateb categori 2