Outlook: Sut i dynnu pob URL o un e-bost

Os yw e-bost yn cynnwys cannoedd o URLau y mae angen eu tynnu i ffeil testun, bydd eu copïo a'u gludo fesul un yn waith diflas. Mae'r tiwtorial hwn yn cyflwyno VBAs a all dynnu pob URL o e-bost yn gyflym.

VBA i echdynnu URLs o un e-bost i ffeil testun

VBA i echdynnu URLs o e-byst lluosog i ffeil Excel

Tab Office - Galluogi Golygu a Phori Tabiau yn Microsoft Office, Gwneud Gwaith yn Awel

Read More ...Dadlwythwch ...

Kutools ar gyfer Outlook - Hwb Outlook gyda 100 + Nodweddion Uwch ar gyfer Effeithlonrwydd Superior

Awtomeiddio e-bostio gyda Auto CC / BCC, Auto Ymlaen gan reolau; anfon Ymateb Auto (Allan o'r Swyddfa) heb fod angen gweinydd cyfnewid...
Cael nodiadau atgoffa fel Rhybudd BCC wrth ymateb i bawb tra'ch bod ar restr BCC, a Atgoffwch Wrth Ymlyniadau ar Goll am atodiadau anghofiedig...
Gwella effeithlonrwydd e-bost gyda Ateb (Pawb) Gydag Atodiadau, Ychwanegu Cyfarchiad neu Dyddiad ac Amser yn Awtomatig i'r Llofnod neu'r Pwnc, Ateb E-byst Lluosog...
Symleiddio e-bostio gyda E-byst Dwyn i gof, Offer Ymlyniad (Cywasgu Pawb, Auto Save All...), Tynnwch y Dyblygion, a Adroddiad Cyflym...

Rhowch hwb i'ch Outlook 2021 - 2010 neu Outlook 365 gyda'r nodweddion uwch hyn. Mwynhewch dreial cynhwysfawr am ddim 60 diwrnod a dyrchafwch eich profiad e-bost!

Read More ...Dadlwythwch ...

VBA i echdynnu URLs o un e-bost i ffeil testun

1. Dewiswch e-bost yr ydych am i echdynnu'r URLs, a phwyswch Alt + F11 allweddi i alluogi Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Cliciwch Mewnosod > Modiwlau i greu modiwl gwag newydd, yna copïwch a gludwch y cod isod i'r modiwl.

VBA: tynnwch bob URL o un e-bost i ffeil testun.

Sub ExportUrlToTextFileFromEmail()
'UpdatebyExtendoffice20220413
  Dim xMail As Outlook.MailItem
  Dim xRegExp As RegExp
  Dim xMatchCollection As MatchCollection
  Dim xMatch As Match
  Dim xUrl As String, xSubject As String, xFileName As String
  Dim xFs As FileSystemObject
  Dim xTextFile As Object
  Dim i As Integer
  Dim InvalidArr
  On Error Resume Next
  If Application.ActiveWindow.Class = olInspector Then
    Set xMail = ActiveInspector.CurrentItem
  ElseIf Application.ActiveWindow.Class = olExplorer Then
    Set xMail = ActiveExplorer.Selection.Item(1)
  End If
  Set xRegExp = New RegExp
  With xRegExp
    .Pattern = "(https?[:]//([0-9a-z=\?:/\.&-^!#$;_])*)"
    .Global = True
    .IgnoreCase = True
  End With
  If xRegExp.test(xMail.Body) Then
    InvalidArr = Array("/", "\", "*", ":", Chr(34), "?", "<", ">", "|")
    xSubject = xMail.Subject
    For i = 0 To UBound(InvalidArr)
      xSubject = VBA.Replace(xSubject, InvalidArr(i), "")
    Next i
    xFileName = "C:\Users\Public\Downloads\" & xSubject & ".txt"
    Set xFs = CreateObject("Scripting.FileSystemObject")
    Set xTextFile = xFs.CreateTextFile(xFileName, True)
    xTextFile.WriteLine ("Export URLs:" & vbCrLf)
    Set xMatchCollection = xRegExp.Execute(xMail.Body)
    i = 0
    For Each xMatch In xMatchCollection
      xUrl = xMatch.SubMatches(0)
      i = i + 1
      xTextFile.WriteLine (i & ". " & xUrl & vbCrLf)
    Next
    xTextFile.Close
    Set xTextFile = Nothing
    Set xMatchCollection = Nothing
    Set xFs = Nothing
    Set xFolderItem = CreateObject("Shell.Application").NameSpace(0).ParseName(xFileName)
    xFolderItem.InvokeVerbEx ("open")
    Set xFolderItem = Nothing
  End If
  Set xRegExp = Nothing
End Sub

Yn y cod hwn, bydd yn creu ffeil testun newydd a enwir gyda'r pwnc e-bost a'i osod yn y llwybr: C:\Defnyddwyr\Cyhoeddus\Lawrlwythiadau, gallwch ei newid yn ôl yr angen.

doc dyfyniad url 1

3. Cliciwch offer > Cyfeiriadau i alluogi Cyfeiriadau – Prosiect 1 ymgom, ticiwch y Mynegiadau Rheolaidd Microsoft VBScript 5.5 blwch gwirio. Cliciwch OK.

doc dyfyniad url 1

4. Gwasgwch F5 allwedd neu cliciwch Run botwm i redeg y cod, nawr mae ffeil testun yn ymddangos ac mae pob URL wedi'i dynnu ynddo.

doc dyfyniad url 1

Nodyn: os ydych chi'n ddefnyddwyr Outlook 2010 ac Outlook 365, ticiwch hefyd y blwch ticio Windows Script Host Object Model yng Ngham 3. Yna cliciwch Iawn.

VBA i echdynnu URLs o e-byst lluosog i ffeil Excel

Os ydych chi am dynnu URLs o negeseuon e-bost dethol lluosog i ffeil Excel, gall cod VBA o dan y cod eich helpu chi.

1. Dewiswch e-bost yr ydych am i echdynnu'r URLs, a phwyswch Alt + F11 allweddi i alluogi Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Cliciwch Mewnosod > Modiwlau i greu modiwl gwag newydd, yna copïwch a gludwch y cod isod i'r modiwl.

VBA: tynnwch bob URL o negeseuon e-bost lluosog i ffeil Excel

'UpdatebyExtendoffice20220414
Dim xExcel As Excel.Application
Dim xExcelWb As Excel.Workbook
Dim xExcelWs As Excel.Worksheet

Sub ExportAllUrlsToExcelFromMultipleEmails()
  Dim xMail As MailItem
  Dim xSelection As Selection
  Dim xWordDoc As Word.Document
  Dim xHyperlink As Word.Hyperlink
  On Error Resume Next
  Set xSelection = Outlook.Application.ActiveExplorer.Selection
  If (xSelection Is Nothing) Then Exit Sub
  Set xExcel = CreateObject("Excel.Application")
  Set xExcelWb = xExcel.Workbooks.Add
  Set xExcelWs = xExcelWb.Sheets(1)
  xExcelWb.Activate
  With xExcelWs
    .Range("A1") = "Subject"
    .Range("B1") = "DisplayText"
    .Range("C1") = "Link"
  End With
  With xExcelWs.Range("A1", "C1").Font
    .Bold = True
    .Size = 12
  End With
  For Each xMail In xSelection
    Set xWordDoc = xMail.GetInspector.WordEditor
    If xWordDoc.Hyperlinks.Count > 0 Then
      For Each xHyperlink In xWordDoc.Hyperlinks
          Call ExportToExcelFile(xMail, xHyperlink)
      Next
    End If
  Next
  xExcelWs.Columns("A:C").AutoFit
  xExcel.Visible = True
End Sub

Sub ExportToExcelFile(curMail As MailItem, curHyperlink As Word.Hyperlink)
  Dim xRow As Integer
  xRow = xExcelWs.Range("A" & xExcelWs.Rows.Count).End(xlUp).Row + 1
  With xExcelWs
    .Cells(xRow, 1) = curMail.Subject
    .Cells(xRow, 2) = curHyperlink.TextToDisplay
    .Cells(xRow, 3) = curHyperlink.Address
  End With
End Sub

Yn y cod hwn, mae'n echdynnu'r holl hyperddolenni a'r testunau arddangos cyfatebol a'r pynciau e-bost.

doc dyfyniad url 1

3. Cliciwch offer > Cyfeiriadau i alluogi Cyfeiriadau – Prosiect 1 ymgom, tic Llyfrgell Gwrthrychau Microsoft Excel 16.0 ac Llyfrgell Gwrthrychau Microsoft Word 16.0 blychau ticio. Cliciwch OK.

doc dyfyniad url 1

4. Yna gosodwch y cyrchwr o fewn y cod VBA, pwyswch F5 allwedd neu cliciwch Run botwm i redeg y cod, nawr mae llyfr gwaith yn ymddangos ac mae pob URL wedi'i dynnu ynddo, yna gallwch chi ei gadw i ffolder.

doc dyfyniad url 1