Sut i gael cyfeiriad e-bost yr anfonwr o un neu fwy o negeseuon e-bost yn Outlook?

Ydych chi erioed wedi ceisio tynnu'r cyfeiriad e-bost o'r maes “O” o un neu fwy o negeseuon e-bost a dderbyniwyd yn Outlook? Mae'r erthygl hon yn darparu cod VBA i'ch helpu i drin y dasg hon.

Cael cyfeiriad e-bost yr anfonwr o un neu fwy o negeseuon e-bost yn Outlook

Rhedwch y cod VBA canlynol i dynnu'r cyfeiriad e-bost o'r maes “O” o un neu fwy o negeseuon e-bost a dderbyniwyd yn Outlook.

1. Agorwch ffolder e-bost, dewiswch neges e-bost yr ydych am gael cyfeiriad e-bost yr anfonwr ohoni. Gwasgwch y Alt + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

Awgrymiadau: I ddewis negeseuon e-bost lluosog, os gwelwch yn dda dal i lawr y Ctrl allweddol ac yna dewiswch yr e-byst fesul un.

2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch Mewnosod > Modiwlau, yna copïwch y cod VBA canlynol i ffenestr y Modiwl (cod).

Cod VBA: tynnwch gyfeiriad e-bost yr anfonwr o un neu fwy o negeseuon e-bost yn Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. Cliciwch offer > Cyfeiriadau, yna gwiriwch y Amser Rhedeg Sgriptio Microsoft blwch yn y Cyfeiriadau – Prosiect1 blwch deialog.

4. Gwasgwch y F5 allwedd i redeg y cod. Yna a Kutools ar gyfer Rhagolwg blwch deialog pops up, rhestru holl gyfeiriadau e-bost anfonwr y negeseuon e-bost a ddewiswyd.

Awgrymiadau:

Os oes angen i chi allforio'r rhestr cyfeiriadau i ffeil txt, cliciwch ar y Ydy botwm.

Neu cliciwch ar y Na botwm i ddod â'r broses i ben.

5. Ar ôl clicio Ydy botwm, a Porwch Am Ffolder blwch deialog pops up. Dewiswch ffolder i gadw'r ffeil a chliciwch ar y OK botwm.

6. Yn olaf, a Kutools ar gyfer Rhagolwg bydd blwch deialog yn ymddangos, gan ddweud wrthych beth yw llwybr y ffeil a allforiwyd. Cliciwch OK i'w gau.

7. Ewch i'r ffolder lle mae'r ffeil allforio yn cael ei gadw ac agorwch y ffeil .txt a enwir cyfeiriad i weld cyfeiriadau e-bost anfonwr y negeseuon e-bost a ddewiswyd.