Sut i fewnforio penblwyddi o Excel i galendr Outlook?

Os oes gennych restr hir o wybodaeth pen-blwydd mewn taflen waith, nawr, rydych chi am fewnforio'r penblwyddi hyn i'ch calendr Outlook fel digwyddiadau. Sut allech chi ddelio â'r dasg hon gyda rhai dulliau cyflym?

Mewnforio penblwyddi o Excel i galendr Outlook gyda chod VBA

Fel rheol, nid oes unrhyw ffordd uniongyrchol i fewnforio'r penblwyddi i galendr Outlook, yma, byddaf yn creu cod VBA i ddatrys y broblem hon, gwnewch y camau canlynol:

1. Agorwch y daflen waith sy'n cynnwys y penblwyddi rydych chi am eu mewnforio i Outlook, ac yna daliwch y ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Cliciwch Mewnosod > Modiwlau, a gludwch y cod canlynol yn y Ffenestr Modiwl.

Cod VBA: Mewnforio penblwyddi i galendr Outlook

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Dal yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch offer > cyfeiriadau. Yn y popped allan Cyfeiriadau - VBAProject blwch deialog, gwirio Llyfrgell Gwrthrychau Microsoft Outlook 16.0 opsiwn o'r Cyfeiriadau sydd ar Gael blwch rhestr, gweler y screenshot:

4. Yna cliciwch OK i gau'r blwch deialog hwn. Nawr, pwyswch F5 allwedd i redeg y cod hwn, ac mae blwch prydlon yn cael ei popio allan, dewiswch yr enw a cholofnau pen-blwydd, gweler y sgrinlun:

5. Ac yna, cliciwch OK botwm, bydd y penblwyddi yn cael eu mewnforio i'r calendr Outlook ar unwaith, gallwch chi lansio'ch Outlook i weld y canlyniad, gweler y sgrinlun: