Sut i symud gwahanol fathau o eitemau wedi'u dileu i ffolderi gwahanol yn awtomatig yn Outlook?

Yn Outlook, bydd pob math o eitemau sydd wedi'u dileu (byst, tasg, cysylltiadau, ac ati) yn cael eu symud i'r ffolder Eitemau wedi'u Dileu. Os ydych chi am symud yr eitemau i wahanol ffolderi yn seiliedig ar y math o eitem o dan y ffolder Eitemau wedi'u Dileu fel y dangosir y sgrinlun isod, sut allwch chi ei wneud yn Outlook?

Symudwch wahanol fathau o eitemau wedi'u dileu i ffolderi gwahanol yn awtomatig gyda chod VBA

Gall y cod VBA isod eich helpu i symud yr eitemau sydd wedi'u dileu i ffolderi gwahanol yn awtomatig, gwnewch fel hyn:

1. Lansio'r Outlook, ac yna, dal i lawr ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Yna, cliciwch ddwywaith SesiwnOutlook oddi wrth y Prosiect-Prosiect1 cwarel, ac yna, copïwch a gludwch y cod isod i'r ffenestr cod gwag:

Cod VBA: Symudwch wahanol fathau o eitemau wedi'u dileu i ffolderi gwahanol yn awtomatig

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Yna, arbedwch y cod hwn, ac ailgychwynwch yr Outlook i actifadu'r cod hwn.

4. O hyn ymlaen, pan fyddwch yn dileu eitem, bydd yn cael ei symud i'r math cyfatebol o ffolder o dan Eitemau wedi'u Dileu ffolder yn awtomatig.

5. I weld y canlyniad, cliciwch eicon ar waelod y cwarel ffolder, ac yna cliciwch Ffolderi i ehangu pob ffolder yn y cwarel, gweler sgrinluniau: