Yn lle rhannu dogfen yn sawl dogfen â llaw, bydd y dull hwn yn cyflwyno VBA i rannu dogfen Word â'r amffinydd penodedig yn Word. Gwnewch fel a ganlyn:

1. Gwasgwch Alt + F11 allweddi gyda'i gilydd i agor ffenestr Microsoft Visual Basic for Application;

2. Cliciwch Mewnosod > Modiwlau, ac yna pastiwch islaw cod VBA i mewn i ffenestr y Modiwl agoriadol newydd.

VBA: Rhannwch Ddogfen Word yn Ddogfennau Lluosog gan Delimiter

Sub SplitNotes(delim As String, strFilename As String)
Dim doc As Document
Dim arrNotes
Dim I As Long
Dim X As Long
Dim Response As Integer
arrNotes = Split(ActiveDocument.Range, delim)
Response = MsgBox("This will split the document into " & UBound(arrNotes) + 1 & " sections.Do you wish to proceed?", 4)
If Response = 7 Then Exit Sub
For I = LBound(arrNotes) To UBound(arrNotes)
If Trim(arrNotes(I)) <> "" Then
X = X + 1
Set doc = Documents.Add
doc.Range = arrNotes(I)
doc.SaveAs ThisDocument.Path & "\" & strFilename & Format(X, "000")
doc.Close True
End If
Next I
End Sub
Sub test()
'delimiter & filename
SplitNotes "///", "Notes "
End Sub

3. Yna cliciwch Run botwm neu pwyswch allwedd F5 i gymhwyso'r VBA.

4. Yn y ddogfen popping allan Microsoft Word, cliciwch y botwm Ie i fynd ymlaen.

Nodyn:
(1) Gwnewch yn siŵr eich bod yn ychwanegu eich amffinydd yr un peth â "///" yn yr is-brawf i'r ddogfen rhwng pob adran o'r testun yr ydych am ei wahanu. Hefyd, gallwch chi newid "///" i unrhyw amffinyddion i ddiwallu'ch angen.
(2) Gallwch chi newid y dogfennau "Nodiadau" yn yr is Brawf i weddu i'ch anghenion.
(3) A bydd y dogfennau hollti yn cael eu cadw i'r un lle â'r ffeil wreiddiol.
(4) Nid oes angen i chi ychwanegu amffinydd at ddiwedd y ffeil wreiddiol, os gwnewch hynny, bydd dogfen wag ar ôl ei hollti.

Dyma VBA arall i'ch helpu chi i rannu un ddogfen Word yn lluosog i luosog yn ôl tudalen yn Word. Gwnewch fel a ganlyn:

1. Gwasgwch Alt + F11 allweddi gyda'i gilydd i agor ffenestr Microsoft Visual Basic for Application;

2. Cliciwch Mewnosod > Modiwlau, ac yna pastiwch islaw cod VBA i mewn i ffenestr y Modiwl agoriadol newydd.

VBA: Rhannwch Ddogfen yn Ddogfennau Lluosog yn ôl Tudalen yn Word

Sub SplitIntoPages()
Dim docMultiple As Document
Dim docSingle As Document
Dim rngPage As Range
Dim iCurrentPage As Integer
Dim iPageCount As Integer
Dim strNewFileName As String
Application.ScreenUpdating = False 'Makes the code run faster and reduces screen _
flicker a bit.
Set docMultiple = ActiveDocument 'Work on the active document _
(the one currently containing the Selection)
Set rngPage = docMultiple.Range 'instantiate the range object
iCurrentPage = 1
'get the document's page count
iPageCount = docMultiple.Content.ComputeStatistics(wdStatisticPages)
Do Until iCurrentPage > iPageCount
If iCurrentPage = iPageCount Then
rngPage.End = ActiveDocument.Range.End 'last page (there won't be a next page)
Else
'Find the beginning of the next page
'Must use the Selection object. The Range.Goto method will not work on a page
Selection.GoTo wdGoToPage, wdGoToAbsolute, iCurrentPage + 1
'Set the end of the range to the point between the pages
rngPage.End = Selection.Start
End If
rngPage.Copy 'copy the page into the Windows clipboard
Set docSingle = Documents.Add 'create a new document
docSingle.Range.Paste 'paste the clipboard contents to the new document
'remove any manual page break to prevent a second blank
docSingle.Range.Find.Execute Findtext:="^m", ReplaceWith:=""
'build a new sequentially-numbered file name based on the original multi-paged file name and path
strNewFileName = Replace(docMultiple.FullName, ".doc", "_" & Right$("000" & iCurrentPage, 4) & ".doc")
docSingle.SaveAs strNewFileName 'save the new single-paged document
iCurrentPage = iCurrentPage + 1 'move to the next page
docSingle.Close 'close the new document
rngPage.Collapse wdCollapseEnd 'go to the next page
Loop 'go to the top of the do loop
Application.ScreenUpdating = True 'restore the screen updating
'Destroy the objects.
Set docMultiple = Nothing
Set docSingle = Nothing
Set rngPage = Nothing
End Sub 

3. Yna cliciwch Run botwm neu wasg F5 allwedd i gymhwyso'r VBA.

Nodyn: Bydd y dogfennau hollti yn cael eu cadw i'r un lle â'r ffeil wreiddiol.

Os oes gennych Kutools for Word wedi'i osod, gallwch gymhwyso ei Hollti swyddogaeth i rannu un ddogfen yn hawdd yn un lluosog yn ôl tudalen, pennawd, toriad adran, neu doriad tudalen fel sydd ei angen arnoch yn Word.

1. Clic Kutools Byd Gwaith > Hollti i alluogi'r Hollti nodwedd.

2. Yn y dialog Hollti agoriadol yn y sgrin, gallwch wneud fel a ganlyn:

(1) Dewiswch y ffordd hollti o'r Wedi'i rannu gan rhestr ostwng.
Mae'r nodwedd hon yn cefnogi 6 ffordd hollti: pennawd 1, seibiannau tudalen, seibiannau adran, tudalennau, pob n tudalen, ac ystodau tudalen arfer fel y dangosir isod y llun:

(2) Cliciwch y Pori botwm  i nodi y ffolder cyrchfan y byddwch yn arbed y dogfennau rhanedig ynddo;

(3) Teipiwch allweddair i mewn fel rhagddodiad enwau dogfennau newydd yn y Rhagddodiad Dogfen blwch.

Awgrym:
(1) Os ydych chi'n nodi'r rhaniad, rhannwch y ddogfen gyfredol â Pob n tudalen, mae angen i chi nodi'r rhif yn y Pob n tudalen blwch;

(2) Os ydych chi'n nodi rhannu'r ddogfen gyfredol yn ôl ystodau tudalennau arfer, mae angen i chi nodi'r ystodau tudalennau arfer hyn sydd wedi'u gwahanu gan atalnodau yn y tudalen blwch, er enghraifft, math 1, 3-5, 12 yn y blwch.

3. Cliciwch y Ok botwm i ddechrau hollti.

Yna mae'r ddogfen gyfredol yn cael ei rhannu â'r ffordd hollti benodol, a bydd dogfennau newydd yn cael eu cadw i'r ffolder cyrchfan mewn swmp.