Tiwtorial Excel - echdynnu testun neu rif yn ôl lleoliad penodol
Mewn llawer o achosion, efallai mai dim ond o frawddeg neu linyn testun y bydd angen i chi ei dynnu o'r cynnwys defnyddiol mewn cell, fel tynnu'r dalaith o'r cyfeiriad, tynnu'r cyfeiriad e-bost o frawddeg, tynnu rhif bil y negesydd o sgwrs, ac yn y blaen. Mae'r tiwtorial hwn yn culhau'r echdynnu i safle penodol mewn cell ac yn casglu gwahanol ddulliau i helpu i dynnu testun neu rifau o gell yn ôl safle penodol yn Excel.
Tabl Cynnwys: [ Cuddio ]
Tynnu testun yn ôl safle
Mae'r adran hon yn casglu safbwyntiau cyffredin lle gellir echdynnu testun o gell ac yn darparu dulliau cyfatebol i'w trin gam wrth gam. Gallwch bori am fwy o fanylion.
1. Tynnwch nifer y nodau o'r chwith neu'r dde
I dynnu nifer y nodau o ochr chwith neu ochr dde llinyn, gallwch roi cynnig ar un o'r dulliau isod.
1.1 Echdynnu'r nodau N cyntaf neu olaf gyda fformiwlâu
Gan dybio bod gennych restr llinynnau testun yng ngholofn B fel y dangosir yn y sgrin lun isod, i dynnu'r 2 nod cyntaf a'r 2 nod olaf o bob llinyn, gallwch gymhwyso'r fformiwlâu canlynol.
Tynnwch y N nodau cyntaf o linyn testun
Gall y swyddogaeth LEFT helpu i dynnu'r nodau N cyntaf yn hawdd o linyn testun yn Excel.
Fformiwla generig
=LEFT(text_string,[num_chars])
Dadleuon
Nawr gallwch chi gymhwyso'r fformiwla hon i dynnu'r 2 nod cyntaf o gelloedd yng ngholofn B.
1. Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad cyntaf. Dewiswch y gell canlyniad a llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla i gelloedd eraill.
=LEFT(B5,2)
Nawr mae'r 2 nod cyntaf ym mhob cell o ystod B5:B10 wedi'u tynnu.
Tynnwch y nodau N olaf o linyn testun
Yma rydym yn cymhwyso'r swyddogaeth CYRCH i dynnu'r nodau N olaf o linyn testun yn Excel.
Fformiwla generig
=RIGHT(text_string,[num_chars])
Dadleuon
Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Yna dewiswch y gell canlyniad hon a llusgwch ei AutoFill Handle i lawr i gael canlyniadau eraill.
=RIGHT(B5,2)
1.2 Tynnwch y nodau N cyntaf neu olaf gyda theclyn anhygoel
Er bod y fformiwlâu uchod yn syml, i dynnu'r nodau n cyntaf neu olaf o restr hir o linyn testun, mae angen i chi lusgo'r AutoFill Handle o'r brig i'r gwaelod o hyd a allai gymryd ychydig o amser. Yma yn argymell Kutools ar gyfer Excel'S Testun Detholiad cyfleustodau i helpu i dynnu'r nodau N cyntaf neu olaf o restr o linyn testun mewn swmp.
1. Dewiswch y rhestr llinyn testun rydych chi am dynnu testun ohoni ymlaen llaw a chliciwch Kutools > Testun > Testun Detholiad.
2. Yn y popping up Testun Detholiad blwch deialog, mae angen i chi ffurfweddu fel a ganlyn.
Nodyn: Er mwyn gwneud y canlyniad yn ddeinamig pan fydd y llinyn testun yn newid, gallwch wirio'r Mewnosod fel fformiwla blwch.
3. Yn y popping nesaf Testun Detholiad blwch deialog, dewiswch gell i allbynnu'r nodau a dynnwyd ac yna cliciwch OK.
Yna mae'r nodau N cyntaf neu olaf penodedig yn cael eu tynnu o gelloedd dethol mewn swmp.
Cliciwch i wybod mwy am y nodwedd hon.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
2. Tynnu testun cyn neu ar ôl nod/gair penodol
I dynnu testun cyn neu ar ôl cymeriad neu air penodol, bydd y gwahanol senarios yn yr adran hon yn cwrdd â'ch anghenion.
2.1 Tynnu testun cyn neu ar ôl yr amffinydd cyntaf (nodwedd)
Fel y dangosir yn y sgrinlun isod, i echdynnu testun cyn neu ar ôl yr amffinydd cyntaf o bob cell yn yr ystod B4: B10, gallwch gymhwyso un o'r dulliau isod.
2.1.1 Tynnu testun cyn yr amffinydd cyntaf gyda fformiwla
Gall cymhwyso fformiwla sy'n seiliedig ar y swyddogaethau CHWITH a FIND helpu i echdynnu testun cyn yr amffinydd cyntaf o gell. Gallwch ddilyn y camau isod i'w gyflawni.
Fformiwla generig
=LEFT(text_string,FIND("delimiter",text_string,1)-1)
Dadleuon
Dewiswch gell wag, copïwch neu rhowch y fformiwla isod i mewn iddi a gwasgwch y Rhowch allweddol i gael y canlyniad cyntaf. Dewiswch y gell canlyniad cyntaf a llusgwch ei AutoFill Handle i lawr i gael y testunau cyn amffinydd cyntaf celloedd eraill.
=LEFT(B5,FIND("-",B5,1)-1)
2.1.2 Tynnu testun ar ôl yr amffinydd cyntaf gyda fformiwla
Mae'r fformiwla isod yn helpu i echdynnu testun ar ôl yr amffinydd cyntaf o gell yn Excel.
Fformiwla generig
=MID(text_string,FIND("delimiter",text_string)+1,LEN(text_string))
Dadleuon
=MID(B5,FIND("-",B5)+1,LEN(B5))
2.1.3 Tynnu testun cyn neu ar ôl yr amffinydd cyntaf gydag offeryn anhygoel
Yma yn argymell yn fawr y Testun Detholiad cyfleustodau Kutools ar gyfer Excel. Gyda'r nodwedd hon, gallwch yn hawdd echdynnu testunau cyn neu ar ôl yr amffinydd cyntaf o ystod o gelloedd mewn swmp.
1. Dewiswch yr ystod o gelloedd lle rydych chi am echdynnu'r testun, ac yna cliciwch Kutools > Testun > Testun Detholiad.
2. Yn y Testun Detholiad blwch deialog, mae angen i chi ffurfweddu fel a ganlyn.
Nodyn: I wneud y canlyniad yn ddeinamig pan fydd y llinyn testun yn newid, gallwch wirio'r Mewnosod fel blwch fformiwla.
3. Yna un arall Testun Detholiad blwch deialog yn ymddangos, dewiswch gell i allbynnu'r canlyniadau a chliciwch OK.
Yna mae testunau cyn neu ar ôl yr amffinydd cyntaf yn cael eu tynnu o gelloedd dethol ar unwaith.
I gael gwybod mwy am y nodwedd hon, ewch i: Tynnu Testun Penodol Yn Gyflym O Gelloedd Yn Excel.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
2.2 Tynnu testun cyn neu ar ôl yr amffinydd olaf (nodwedd)
Yn y camau uchod rydym wedi dysgu'r dulliau ar gyfer echdynnu testun cyn neu ar ôl yr amffinydd cyntaf o gell. Fel y dangosir yn y sgrinlun isod, bydd yr adran hon yn dangos dwy fformiwla i chi dynnu testun cyn neu ar ôl yr amffinydd olaf o gell. Gallwch ddilyn y camau isod i'w gyflawni.
2.2.1 Tynnu testun cyn yr amffinydd olaf gyda fformiwla
I echdynnu testun cyn y amffinydd olaf o gell, gallwch ddefnyddio'r swyddogaethau CHWILIO, LEN a SUBSTITUTE y tu mewn i'r ffwythiant CHWITH.
Fformiwla generig
=LEFT(text_string,SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter",""))))-1)
Dadleuon
Dewiswch gell, nodwch y fformiwla isod a gwasgwch y botwm Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon a llusgwch ei AutoFill Handle i lawr i dynnu'r testunau o linynnau testun eraill yn yr un golofn.
=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)
2.2.2 Tynnu testun ar ôl yr amffinydd olaf gyda fformiwla
Ar ôl echdynnu testun cyn y amffinydd olaf o gell, gallwch gymhwyso'r fformiwla isod i echdynnu'r testun ar ôl y amffinydd olaf yn ôl yr angen.
Fformiwla generig
=RIGHT(text_string,LEN(text_string)-SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter","")))))
Dadleuon
Dewiswch gell, nodwch y fformiwla isod a gwasgwch y botwm Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon a llusgwch ei AutoFill Handle i lawr i dynnu'r testunau o linynnau testun eraill yn yr un golofn.
=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))
2.3 Tynnu testun ar ôl yr nfed nod
Edrychwch ar yr enghraifft isod, mae rhestr o linyn testun yn yr ystod B4:B10, i echdynnu'r testun ar ôl y trydydd nod o bob cell, gallwch gymhwyso fformiwla yn seiliedig ar y swyddogaeth MID a'r swyddogaeth LEN.
Fformiwla generig
=MID(text_string,nth_char+1,LEN(text_string))
Dadleuon
Dewiswch gell wag, copïwch neu rhowch y fformiwla isod i mewn iddi a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon a llusgwch ei AutoFill Handle i lawr i gael canlyniadau eraill.
=MID(B5,3+1,LEN(B5))
2.4 Tynnwch yr nfed gair o linyn testun
Gan dybio bod gennych restr o linyn testun fel y dangosir yn y sgrin isod, ac eisiau tynnu'r nfed gair yn unig o'r llinyn testun, mae'r adran hon yn darparu tri dull i chi ei wneud.
2.4.1 Echdynnu'r nfed gair gyda fformiwla
Gallwch gyfuno'r ffwythiannau TRIM, MID, SUBSTITUTE, REPT a LEN i echdynnu'r nfed gair o linyn testun mewn cell.
Fformiwla generig
=TRIM(MID(SUBSTITUTE(text_string," ",REPT(" ",LEN((text_string))), (N-1)*LEN((text_string)+1, LEN((text_string)))
Dadleuon
Yn yr achos hwn, mae'r ystod B5:B10 yn cynnwys y llinynnau testun, mae D5: D10 yn cynnwys y rhifau sy'n cynrychioli'r nfed gair, gadewch i ni gymhwyso'r fformiwla hon i dynnu'r nfed gair o'r llinyn testun.
Dewiswch gell wag, copïwch neu rhowch y fformiwla isod i mewn iddi a gwasgwch y Rhowch allweddol i gael y canlyniad cyntaf. Dewiswch y gell canlyniad hon a llusgwch ei AutoFill Handle i lawr i gael yr nfed gair o gelloedd eraill.
=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))
Nodyn: Gallwch chi deipio'r nfed rhif yn uniongyrchol yn y fformiwla fel a ganlyn.
=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))
2.4.2 Echdynnu'r nfed gair gyda ffwythiant a ddiffinnir gan y Defnyddiwr
Ar wahân i'r fformiwla uchod, gallwch hefyd gymhwyso swyddogaeth a ddiffinnir gan y defnyddiwr i dynnu'r nfed gair o gell yn Excel.
1. Gwasgwch y Alt + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.
2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch Mewnosod > Modiwl, ac yna copïwch y VBA isod i'r ffenestr Cod.
Cod VBA: Tynnwch yr nfed gair o linyn testun mewn cell
Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
FindWord = ""
Else
FindWord = arr(Position - 1)
End If
End Function
3. Gwasgwch y Alt + Q allweddi i gau'r Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.
4. Ewch yn ôl i'r daflen waith sy'n cynnwys y llinynnau testun yr ydych am dynnu'r nfed gair ohonynt. Dewiswch gell wag, copïwch neu rhowch y fformiwla isod ynddi a gwasgwch y Rhowch allwedd i gael yr nfed gair.
=FindWord(B5,D5)
Or
=FindWord(B5,2)
Nodyn: yn y fformiwla, D5 yw'r gell sy'n cynnwys rhif sy'n cynrychioli'r nfed gair. Fel arall, gallwch ddisodli'r cyfeirnod cell yn uniongyrchol â rhif.
5. Dewiswch y gell canlyniad a llusgwch ei AutoFill Handle i lawr i dynnu'r nfed gair o linynnau testun celloedd eraill.
2.4.3 Tynnwch yr nfed gair gyda theclyn anhygoel
Os nad ydych chi am gymhwyso fformiwla neu swyddogaeth a ddiffinnir gan y defnyddiwr a ddarperir uchod â llaw, dyma argymell Kutools ar gyfer Excel's Tynnwch y nawfed gair yn y gell cyfleustodau. Gyda'r nodwedd hon, gallwch chi dynnu'r nfed gair yn hawdd o linyn testun mewn cell gydag ychydig o gliciau yn unig.
1. Dewiswch gell i osod y canlyniad, a chliciwch Kutools > Cynorthwyydd Fformiwla > Testun > Detholiad yr nfed gair mewn cell. Gweler y screenshot:
2. Yn y Cynorthwyydd Fformiwlâu blwch deialog, mae angen i chi ffurfweddu fel a ganlyn.
3. Yna mae'r nfed (ail) gair yn cael ei dynnu o'r llinyn testun yn y gell B5, a gallwch weld fformiwla yn cael ei chreu ar yr un pryd. Dewiswch y gell canlyniad hon a llusgwch ei AutoFill Handle i lawr i gael yr nfed gair o linynnau testun eraill.
Cliciwch i wybod mwy am y nodwedd hon.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
2.5 Tynnu testun cyn neu ar ôl yr nfed digwyddiad o amffinydd
Gan dybio bod gennych restr o linynnau testun fel y dangosir yn y screenshot isod. Er mwyn echdynnu'r testun cyn neu ar ôl yr ail ddigwyddiad o fylchau, mae'r adran hon yn darparu dwy fformiwla i'ch helpu i wneud hynny.
2.5.1 Tynnu testun cyn yr nawfed amffinydd
Gallwch ddefnyddio'r ffwythiant CHWITH ynghyd â'r swyddogaethau SUBSTITUTE a FIND i echdynnu testun cyn i'r nfed amffinydd ddigwydd o gell yn Excel.
Fformiwla generig
=LEFT(SUBSTITUTE(text_string,"delimiter",CHAR(9),n),FIND(CHAR(9),SUBSTITUTE(text_string,"delimiter",CHAR(9),n),1)-1)
Dadleuon
Dewiswch gell, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon a llusgwch ef AutoFill Handle i lawr i gael canlyniadau eraill yn y rhestr.
=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)
Nodyn: Yn y fformiwla, B5 yw'r gell sy'n cynnwys y llinyn testun yr ydych am dynnu'r testun ohono; “ ” yma yn cynrychioli gofod ac mae’r rhif 2 yn cynrychioli ail ddigwyddiad gofod. Gallwch eu newid yn ôl eich anghenion.
2.5.2 Tynnu testun ar ôl yr nfed digwyddiad o amffinydd
I echdynnu testun ar ôl yr nfed digwyddiad o amffinydd, gallwch gymhwyso'r swyddogaeth DDE gyda'r swyddogaethau SUBSTITUTE, LEN a FIND.
Fformiwla generig
=RIGHT(SUBSTITUTE(text_string, "delimiter", CHAR(9), n), LEN(text_string)- FIND(CHAR(9), SUBSTITUTE(text_string, "delimiter", CHAR(9), n), 1) + 1)
Dadleuon
Nawr gallwch chi gymhwyso'r fformiwla hon i echdynnu'r testun ar ôl ail ddigwyddiad y gofod o bob cell yn ystod B5:B10 fel a ganlyn.
Dewiswch gell, nodwch y fformiwla isod a gwasgwch y botwm Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon a'i llusgo AutoFill Handle i lawr i gael canlyniadau eraill.
=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)
2.6 Tynnu testun cyn neu ar ôl toriad llinell
Tybiwch fod gennych restr archebion yng ngholofn B a'ch bod am dynnu'r rhan dyddiad a rhan y cynnyrch yn unig o bob cell. Gallwch ddefnyddio'r fformiwlâu Excel isod i'w wneud.
2.6.1 Tynnu testun cyn toriad y llinell gyntaf â fformiwla
Fel y gwelwch yn y sgrin uchod, mae'r rhan dyddiad yn lleoli cyn toriad llinell gyntaf y gell. Bydd yr adran hon yn dangos swyddogaeth CHWITH ynghyd â swyddogaeth CHWILIO i'ch helpu i echdynnu'r testun cyn toriad y llinell gyntaf o fewn cell.
Fformiwla generig
=LEFT(cell, SEARCH(CHAR(10), cell)-1)
Dadleuon
Dewiswch gell wag, copïwch neu rhowch y fformiwla isod i mewn iddi a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
=LEFT(B5, SEARCH(CHAR(10), B5)-1)
Yna gallwch weld y testun cyn i'r toriad llinell gyntaf ym mhob cell yn ystod B5:B8 gael ei dynnu fel y dangosir yn y sgrin isod.
Nodyn: Yn y fformiwla, mae CHAR(10) yn cynrychioli toriad llinell ar Windows.
2.6.2 Tynnu testun ar ôl toriad y llinell olaf â'r fformiwla
Yn y cam blaenorol, buom yn siarad am sut i dynnu testun cyn toriad y llinell gyntaf o fewn cell. A bydd y rhan hon yn eich arwain sut i echdynnu testun ar ôl y toriad llinell olaf o fewn cell gyda fformiwla wahanol.
Fformiwla generig
=TRIM(RIGHT(SUBSTITUTE(cell,CHAR(10),REPT(" ",200)),200))
Dadleuon
Dewiswch gell wag, rhowch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla i gelloedd eraill.
=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))
Yna y cynnyrch dim. mae rhan o bob cell yn y rhestr yn cael ei dynnu fel y dangosir yn y screenshot uchod.
Nodyn: Yn y fformiwla, mae CHAR(10) yn cynrychioli toriad llinell ar Windows.
2.7 Tynnu testun cyn neu ar ôl gair
Yn y rhannau blaenorol, rydym wedi dysgu sut i echdynnu testun cyn neu ar ôl cymeriad neu amffinydd. Beth ddylech chi ei wneud i echdynnu testun cyn neu ar ôl gair cyfan? Bydd yr adran hon yn cyflwyno tri dull i'ch helpu i gyflawni'r dasg hon.
2.7.1 Tynnu testun o flaen gair arbennig gyda fformiwla
Mae'r fformiwla ganlynol yn eich helpu i echdynnu testun cyn gair penodol o fewn cell yn Excel.
Fformiwla generig
=IFERROR(LEFT(cell,FIND(word,cell)-1),cell)
Dadleuon
Dewiswch gell wag, rhowch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
Yn yr enghraifft hon, rydyn ni'n mynd i dynnu pob testun cyn y gair “Excel”, felly rydyn ni'n teipio'r gair yn uniongyrchol yn y fformiwla a'i amgáu mewn dyfyniadau dwbl. Neu gallwch gyfeirio at gell sy'n cynnwys y gair “Excel”.
=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)
Nodiadau:
2.7.2 Tynnu testun ar ôl gair arbennig gyda fformiwla
I echdynnu testun ar ôl gair penodol, gallwch gymhwyso'r fformiwla ganlynol i'w wneud.
Fformiwla generig
=TRIM(MID(cell,SEARCH(word,cell)+LEN(word),255))
Dadleuon
Dewiswch gell, nodwch y fformiwla isod a gwasgwch y botwm Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))
Yna gallwch weld yr holl destunau ar ôl i'r gair “Excel” ym mhob cell gael ei dynnu fel y dangosir yn y sgrin isod.
Nodiadau:
2.7.3 Tynnu testun cyn neu ar ôl gair penodol gyda theclyn anhygoel
Os ydych chi'n teimlo y gallai defnyddio fformiwla achosi llawer o anghyfleustra, dyma argymell yn gryf y Testun Detholiad cyfleustodau Kutools ar gyfer Excel. Mae'r nodwedd hon yn helpu i awtomeiddio'r dasg Echdynnu yn Excel gyda dim ond ychydig o gliciau.
1. Cliciwch Kutools > Testun > Testun Detholiad i alluogi'r nodwedd hon.
2. Yn y Testun Detholiad blwch deialog, gwnewch y gosodiadau canlynol.
Nodiadau: Os ydych chi am greu canlyniadau deinamig, gwiriwch y Mewnosod fel fformiwla bocs. Yna bydd y canlyniadau'n cael eu diweddaru'n awtomatig pan fydd y data yn yr ystod yn newid.
3. Yna an Testun Detholiad blwch deialog pops i fyny, mae angen i chi ddewis cell i allbwn y canlyniad ac yna cliciwch ar y OK botwm.
Yna mae testunau cyn neu ar ôl gair penodol o fewn pob cell yn yr ystod a ddewiswyd yn cael eu tynnu ar unwaith.
Nodyn: Mae'r nodwedd hon yn sensitif i achosion.
Cliciwch i wybod mwy am y nodwedd hon.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
3. Darn rhwng cymeriadau/geiriau
Os ydych chi am echdynnu testun rhwng nodau neu eiriau penodol, rhowch gynnig ar y dulliau canlynol.
3.1 Tynnu testun rhwng dau nod
I dynnu testun rhwng dau nod, a all fod yr un nodau neu nodau gwahanol. Mae'r adran hon yn darparu nifer o ddulliau, a gallwch ddewis un ohonynt yn ôl eich anghenion.
3.1.1 Echdynnu testun rhwng dau nod tebyg gyda fformiwla
Fel y dangosir yn y sgrin isod, mae rhestr o linynnau testun yng ngholofn B, ac rydych chi am dynnu'r rhan rhif rhwng cymeriadau “/” o bob cell yn yr ystod, gall y fformiwla ganlynol wneud ffafr i chi.
Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad ac yna llusgwch ef AutoFill Handle i lawr i gael canlyniadau celloedd eraill yn y rhestr.
=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")
Yna mae'r testun rhwng dau un nod “/” yn cael ei dynnu o bob cell yn yr ystod. Gweler y sgrinlun:
Nodyn:
3.1.2 Echdynnu testun rhwng dau nod gwahanol gyda fformiwla
Ar ôl dysgu sut i echdynnu testun rhwng dau un nod o fewn cell, yma byddwn yn dangos fformiwla i echdynnu testun rhwng dau nod gwahanol. Fel y dangosir yn y screenshot isod, i echdynnu dim ond y cyfeiriad e-bost rhwng y “<” a “>” o bob cell yng ngholofn B, gallwch wneud fel a ganlyn.
Fformiwla generig
=MID(LEFT(cel,FIND("end_char",cell)-1),FIND("start_char",cell)+1,LEN(cell))
Dadleuon
Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))
Gallwch weld mai dim ond y testun rhwng y nodau penodedig sy'n cael ei dynnu fel y dangosir yn y sgrinlun uchod.
3.1.3 Echdynnu testun rhwng dau gymeriad gyda theclyn anhygoel
Yma yn argymell yn fawr y Tynnu llinynnau rhwng testun penodol nodwedd o Kutools ar gyfer Excel i'ch helpu chi i echdynnu testun yn hawdd rhwng dau gymeriad tebyg neu wahanol o fewn cell yn Excel.
1. Dewiswch gell wag i allbwn y canlyniad, ac yna cliciwch Kutools > Cynorthwyydd Fformiwla > Cynorthwyydd Fformiwla.
2. Yn y Cynorthwyydd Fformiwlâu blwch deialog, gwnewch y gosodiadau canlynol.
3. Yna dim ond y testun rhwng “<” a “>” o fewn cell B5 sy'n cael ei dynnu. Yn y cyfamser, mae fformiwla wedi'i chreu, gallwch ddewis y gell canlyniad hon ac yna llusgo ei AutoFill Handle i lawr i dynnu testunau o gelloedd eraill yn yr un rhestr.
Cliciwch i wybod mwy am y nodwedd hon.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
3.1.4 Tynnu testun rhwng dau nod (gan gynnwys y nodau) fesul rheol
Os ydych chi am gadw'r ddau gymeriad ar ôl echdynnu, ceisiwch gymhwyso rheol yn y Testun Detholiad nodwedd o Kutools ar gyfer Excel.
1. Cliciwch Kutools > Testun > Testun Detholiad.
2. Yn y Testun Detholiad blwch deialog, gwnewch y gosodiadau canlynol.
3. Un arall Testun Detholiad blwch deialog yn ymddangos, dewiswch gell i allbynnu'r canlyniad, ac yna cliciwch ar y OK botwm.
Yna mae'r testun rhwng nodau penodedig (gan gynnwys y cymeriadau) yn cael eu tynnu o bob cell yn yr ystod a ddewiswyd mewn swmp.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
3.2 Echdynnu testun rhwng dau air
Yn ogystal â thynnu testun rhwng dau nod, efallai y bydd angen i chi hefyd dynnu testun rhwng dau air. Er enghraifft, tynnwch yr holl linynnau testun rhwng dau air “KTE” a “nodwedd” o bob cell yng ngholofn B fel y dangosir yn y sgrin lun isod. Gallwch roi cynnig ar un o'r dulliau canlynol i'w wneud.
3.2.1 Tynnu testun rhwng dau air gyda fformiwla
Gallwch ddefnyddio fformiwla sy'n seiliedig ar y ffwythiant MID a'r ffwythiant CHWILIO i echdynnu'r holl linynnau testun rhwng dau air o fewn cell.
Fformiwla generig
=MID(cell,SEARCH("start_word",cell)+3,SEARCH("end_word",cell)-SEARCH("start_word",cell)-4)
Dadleuon
Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)
Nodyn: Yn y fformiwla, mae'r rhif 3 yn cynrychioli hyd nod y gair "KTE"; mae'r rhif 4 yn cynrychioli hyd nod y gair "KTE" ynghyd ag 1.
Gallwch weld pob llinyn testun rhwng y ddau air penodedig yn cael eu tynnu o bob cell yng ngholofn B.
3.2.2 Tynnu testun rhwng dau air gyda theclyn anhygoel
I lawer o ddefnyddwyr Excel, gall fod yn anodd cofio a thrin fformiwlâu. Yma, gyda'r Tynnu llinynnau rhwng testun penodol nodwedd o Kutools ar gyfer Excel, gallwch chi dynnu testun yn hawdd rhwng dau air gyda dim ond ychydig o gliciau.
1. Dewiswch gell i allbwn y canlyniad, ac yna cliciwch Kutools > Cynorthwyydd Fformiwla > Cynorthwyydd Fformiwla.
2. Yn y Cynorthwyydd Fformiwla blwch deialog, mae angen i chi ffurfweddu fel a ganlyn.
3. Yna caiff yr holl linynnau testun rhwng dau air “KTE” a “nodwedd” o fewn cell B5 ei dynnu. Yn y cyfamser, mae fformiwla wedi'i chreu, gallwch ddewis y gell canlyniad hon ac yna llusgo ei AutoFill Handle i lawr i dynnu testunau o gelloedd eraill yn yr un rhestr.
Os ydych chi am gael treial am ddim (30 diwrnod) o'r cyfleustodau hwn, cliciwch i'w lawrlwytho, ac yna ewch i gymhwyso'r llawdriniaeth yn ôl y camau uchod.
Tynnu rhifau yn ôl safle
Ar gyfer rhestr o linynnau alffaniwmerig, gall fod tri achos:
- Mae'r rhif ar ddechrau'r testun;
- Mae'r rhif ar ddiwedd y testun;
- Gall y rhif fod yn unrhyw le yn y testun.
Yn yr adran hon, byddwn yn darparu gwahanol ddulliau y gellir eu defnyddio i echdynnu'r rhifau ym mhob achos a grybwyllir uchod.
1 Echdynnu rhif o ochr chwith llinyn
Bydd y rhan hon yn cyflwyno fformiwla i'ch helpu i echdynnu rhifau sy'n ymddangos cyn testun mewn cell yn unig.
Fformiwla generig
=LEFT(cell, MATCH(FALSE, ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell)+1)), 1) *1), 0) -1)
Dadleuon
Nodyn:
Dewiswch gell wag, nodwch y fformiwla isod a gwasgwch Ctrl + Symud + Rhowch or Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gael niferoedd o gelloedd eraill.
=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)
Nodiadau:
2 Echdynnu rhif o ochr dde llinyn
Fel y dangosir yn y sgrin isod, i dynnu dim ond y niferoedd sy'n ymddangos ar ôl testun mewn cell, rhowch gynnig ar y fformiwla ganlynol.
Fformiwla generig
=RIGHT(cell, LEN(cell) - MAX(IF(ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(cell))), 0)))
Dadleuon
Nodyn:
Dewiswch gell wag, nodwch y fformiwla isod a gwasgwch Ctrl + Symud + Rhowch or Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gael niferoedd o gelloedd eraill.
=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))
Nodiadau:
3. Tynnwch yr holl rifau o unrhyw safle mewn llinyn testun
Mae'r dulliau uchod yn helpu i dynnu rhif yn unig o ochr chwith neu dde llinyn testun. Os ydych chi am dynnu'r holl rifau o unrhyw le mewn llinyn testun, yma rydyn ni'n darparu tri dull i chi ei wneud.
3.1 Tynnwch bob rhif o unrhyw le mewn llinyn â fformiwla
Gallwch gymhwyso'r fformiwla ganlynol i dynnu pob rhif o unrhyw le mewn llinyn testun yn Excel.
1. Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allwedd i gael yr holl rifau o'r gell B5.
=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)
2. Dewiswch y gell canlyniad ac yna llusgwch ei AutoFill Handle i lawr i gael yr holl niferoedd o gelloedd eraill.
3.2 Tynnwch yr holl rifau o unrhyw le mewn llinyn gyda VBA
Mae'r fformiwla uchod yn rhy hir a chymhleth i lawer o ddefnyddwyr Excel. Mewn gwirionedd, gallwch chi redeg sgript VBA i awtomeiddio'r dasg yn Excel. Gallwch chi wneud fel a ganlyn.
1. Gwasgwch y Alt + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.
2. Yn yr agoriad Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch Mewnosod > Modiwl. Yna copïwch y VBA isod i ffenestr cod y Modiwl.
Cod VBA: Tynnwch yr holl rifau o unrhyw le mewn llinyn testun
Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
Dim xRg As Range
Dim xDRg As Range
Dim xRRg As Range
Dim nCellLength As Integer
Dim xNumber As Integer
Dim strNumber As String
Dim xTitleId As String
Dim xI As Integer
xTitleId = "KutoolsforExcel"
Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
If TypeName(xDRg) = "Nothing" Then Exit Sub
Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
If TypeName(xRRg) = "Nothing" Then Exit Sub
xI = 0
strNumber = ""
For Each xRg In xDRg
xI = xI + 1
nCellLength = Len(xRg)
For xNumber = 1 To nCellLength
If IsNumeric(Mid(xRg, xNumber, 1)) Then
strNumber = strNumber & Mid(xRg, xNumber, 1)
End If
Next xNumber
xRRg.Item(xI) = strNumber
strNumber = ""
Next xRg
End Sub
3. Gwasgwch y F5 allwedd i redeg y cod. Yn yr agoriad Kutoolsorexcel blwch deialog, dewiswch yr ystod o gelloedd lle rydych chi am dynnu'r holl rifau o bob cell, ac yna cliciwch ar y OK botwm.
4. Yna un arall Kutoolsorexcel blwch deialog pops up. Yn y blwch deialog hwn, dewiswch gell cyrchfan a chliciwch OK.
Yna mae pob rhif yn cael ei dynnu o bob cell yn yr ystod a ddewiswyd mewn swmp.
4. Tynnu rhifau ar ôl testun penodol
Fel y dangosir yn y sgrin isod, i echdynnu unrhyw rifau ar ôl y testun penodol “Na.”, mae'r adran hon yn darparu dau ddull i'ch helpu i wneud hynny.
4.1 Tynnu rhifau ar ôl testun penodol gyda fformiwla
Gallwch chi gymhwyso'r fformiwla ganlynol i dynnu rhifau ar ôl testun penodol mewn cell yn Excel.
Fformiwla generig:
=LOOKUP(10^6,1*MID(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789",FIND("text"," "&cell&" "))),{2,3,4,5,6}))
Dadleuon
Dewiswch gell wag, copïwch neu nodwch y fformiwla isod a gwasgwch y Rhowch allweddol i gael y canlyniad. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))
Nodiadau:
4.2 Tynnu rhifau ar ôl testun penodol gyda swyddogaeth a ddiffinnir gan y defnyddiwr
Gall y swyddogaeth ganlynol a ddiffinnir gan y defnyddiwr hefyd helpu i echdynnu rhifau ar ôl testun penodol mewn cell. Gwnewch fel a ganlyn.
1. Gwasgwch y Alt + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.
2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch Mewnosod > Modiwl, ac yna copïwch y cod VBA isod i ffenestr cod y Modiwl.
Cod VBA: echdynnu rhifau ar ôl testun penodol mewn cell
Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
xValue = Rng.Text
xStart = InStr(1, xValue, Char, vbTextCompare)
If IsEmpty(xStart) Then
GetNumberAfterTheChar = ""
Exit Function
End If
If xStart < 1 Then
GetNumberAfterTheChar = ""
Exit Function
End If
xStart = xStart - 1 + Len(Char)
If xStart < 1 Then
GetNumberAfterTheChar = ""
Exit Function
End If
xValue = Mid(xValue, xStart + 1)
xRntString = ""
For xI = 1 To Len(xValue)
xC = Mid(xValue, xI, 1)
Select Case Asc(xC)
Case 48 To 57
xRntString = xRntString & xC
Case Else
Exit For
End Select
Next
GetNumberAfterTheChar = xRntString
End Function
3. Gwasgwch y Alt + Q allweddi i gau'r Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.
4. Dewiswch gell, nodwch y fformiwla isod a gwasgwch y Rhowch cywair. Dewiswch y gell canlyniad hon ac yna llusgwch ei AutoFill Handle i lawr i gymhwyso'r fformiwla hon i gelloedd eraill.
=GetNumberAfterTheChar(B5,"No. ")
Nodiadau:
Erthyglau cysylltiedig:
Tiwtorial Excel: Rhannwch Testun, Rhif, a Chelloedd Dyddiad (Ar Wahân yn Golofnau Lluosog)
Rhennir y tiwtorial hwn yn dair rhan: celloedd testun hollti, celloedd rhif hollti a chelloedd dyddiad hollti. Mae pob rhan yn darparu gwahanol enghreifftiau i'ch helpu chi i wybod sut i drin y swydd hollti wrth ddod ar draws yr un broblem.
Cliciwch i wybod mwy ...
Excel Ychwanegu Testun A Rhif I'r Safle Penodedig O'r Cell
Yn Excel, mae ychwanegu testunau neu rifau at gelloedd yn swydd gyffredin iawn. Megis ychwanegu gofod rhwng enwau, ychwanegu rhagddodiad neu ôl-ddodiad i gelloedd, ychwanegu llinellau toriad at rifau cymdeithasol. Yma yn y tiwtorial hwn, mae'n rhestru bron pob un o'r senarios ychwanegu yn Excel ac yn darparu'r dulliau cyfatebol i chi.
Cliciwch i wybod mwy ...
Excel Dileu Cymeriadau, Geiriau, Rhifau O Llinynnau Testun
Gan dybio, mae gennych restr hir o dannau testun sy'n cynnwys nodau, rhifau neu symbolau penodol eraill. Mewn achos penodol, efallai y bydd angen i chi dynnu rhai cymeriadau yn seiliedig ar safle, megis o'r dde, chwith neu ganol o'r tannau testun, neu ddileu rhai nodau diangen, rhifau o'r rhestr o dannau. Bydd dod o hyd i'r atebion fesul un yn rhoi cur pen i chi, mae'r tiwtorial hwn yn casglu pob math o ddulliau ar gyfer tynnu cymeriadau, geiriau neu rifau yn Excel.
Cliciwch i wybod mwy ...
Offer Cynhyrchiant Swyddfa Gorau
Supercharge Eich Sgiliau Excel gyda Kutools ar gyfer Excel, a Phrofiad Effeithlonrwydd Fel Erioed Erioed. Kutools ar gyfer Excel Yn Cynnig Dros 300 o Nodweddion Uwch i Hybu Cynhyrchiant ac Arbed Amser. Cliciwch Yma i Gael Y Nodwedd Sydd Ei Angen Y Mwyaf...
Mae Office Tab yn dod â rhyngwyneb Tabbed i Office, ac yn Gwneud Eich Gwaith yn Haws o lawer
- Galluogi golygu a darllen tabbed yn Word, Excel, PowerPoint, Cyhoeddwr, Mynediad, Visio a Phrosiect.
- Agor a chreu dogfennau lluosog mewn tabiau newydd o'r un ffenestr, yn hytrach nag mewn ffenestri newydd.
- Yn cynyddu eich cynhyrchiant 50%, ac yn lleihau cannoedd o gliciau llygoden i chi bob dydd!