Excel CHOOSE swyddogaeth
- Ex1 - Defnydd sylfaenol: defnyddio CHOOSE gweithredu ar eich pen eich hun i ddewis gwerth o ddadl rhestr
- Ex2 - Dychwelwch ganlyniadau gwahanol yn seiliedig ar gyflyrau lluosog
- Ex3 - Dychwelwch wahanol ganlyniadau wedi'u cyfrifo yn seiliedig ar amodau
- Ex4 - Dewis ar hap o'r rhestr
- Ex5 - Cyfuno CHOOSE ac VLOOKUP swyddogaethau i ddychwelyd gwerth yn y golofn chwith
- Ex6 - Dychwelyd yn ystod yr wythnos neu'r mis yn seiliedig ar y dyddiad penodol
- Ex7 - Dychwelwch i'r dyddiad diwrnod gwaith / penwythnos nesaf yn seiliedig ar heddiw
Disgrifiad
Mae CHOOSE swyddogaeth yn dychwelyd gwerth o'r rhestr o ddadl gwerth yn seiliedig ar y rhif mynegai a roddir. Er enghraifft, CHOOSE(3,”Apple”,”Peach”,”Orange”) yn dychwelyd Oren, y rhif mynegai yw 3, ac Orange yw'r trydydd gwerth ar ôl rhif mynegai yn y swyddogaeth.
cystrawen a Dadleuon
Cystrawen fformiwla
| CHOOSE(index_num, value1, [value2], …) |
Dadleuon
|
Value1, value2… Gall fod yn rhifau, testunau, fformwlâu, cyfeiriadau celloedd, neu enw diffiniedig.
Gwerth Dychwelyd
Mae CHOOSE swyddogaeth yn dychwelyd gwerth o restr yn seiliedig ar y sefyllfa a roddir.
Defnydd ac Enghreifftiau
Yn y rhan hon, rwy'n rhestru rhai enghreifftiau syml ond cynrychioliadol i egluro'r defnydd o'r CHOOSE swyddogaeth.
Ex1 - Defnydd sylfaenol: defnyddio CHOOSE gweithredu ar eich pen eich hun i ddewis gwerth o ddadl rhestr
Fformiwla1:
=CHOOSE(3,"a","b","c","d")
Dychwelwch: c, sef y drydedd ddadl ar ôl y index_num o 3 yn y CHOOSE swyddogaeth.
Sylwch: gan ddefnyddio dyfynbrisiau dwbl sy'n amgylchynu'r gwerth os yw'n destun.
Fformiwla2:
=CHOOSE(2,A1,A2,A3,A4)
Dychweliad: Kate, gwerth A2. Gan fod y index_num yn 2, ac A2 yw'r ail werth yn y CHOOSE swyddogaeth.
Fformiwla3:
=CHOOSE(4,8,9,7,6)
Dychwelwch: 6, y 4edd ddadl rhestr yn y swyddogaeth.
Ex2 - Dychwelwch ganlyniadau gwahanol yn seiliedig ar gyflyrau lluosog
Gan dybio bod gennych chi restr o wyriadau ar gyfer pob cynnyrch yr oedd angen ei labelu yn seiliedig ar yr amodau fel y dangosir isod y screenshot.
Fel arfer, gallwch chi ddefnyddio'r swyddogaeth IF i drin, ond dyma fi'n cyflwyno sut i ddefnyddio'r CHOOSE swyddogaeth i ddatrys y broblem hon yn hawdd
Fformiwla:
=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")
Esboniwch:
(B7>0)+(B7>1)+(B7>5): y index_num, B7 yw 2, sy'n fwy na 0 ac 1 ond yn llai na 5, felly rydyn ni'n cael y canlyniad canolradd:
=CHOOSE(True+Ture+False,"Top","Middle","Bottom")
Fel y gwyddom, Gwir = 1, Anghywir = 0, felly gellir ystyried y fformiwla fel:
=CHOOSE(1+1+0,"Top","Middle","Bottom")
Yna,
=CHOOSE(2,"Top","Middle","Bottom")
Canlyniad: Canol
Ex3 - Dychwelwch wahanol ganlyniadau wedi'u cyfrifo yn seiliedig ar amodau
Gan dybio bod angen i chi gyfrifo'r ad-daliadau ar gyfer pob cynnyrch yn seiliedig ar y swm a'r pris fel y nodir isod.
Fformiwla:
=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
Esboniwch:
(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 yw 102, sy'n fwy na 100 ond yn llai na 201, felly yn y rhan hon, mae'n dychwelyd y canlyniad a ddangosir fel:
=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
Yna,
=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: mae'r gwerthoedd i ddewis ohonynt, ad-daliad yn cyfateb i bris * swm * ad-daliad y cant, oherwydd yma index_num yw 2, mae'n dewis B8 * C8 * 0.2
Dychweliadau: 102 * 2 * 0.2 = 40.8
Yn Excel, weithiau, efallai y bydd angen i chi ddewis gwerth ar hap o restr benodol, y CHOOSE gall swyddogaeth ddatrys y swydd hon.
Dewiswch un gwerth ar hap o restr:
Fformiwla:
=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)
Esboniwch:
RANDBETWEEN(1,5): index_num, sicrhau rhif rhwng 1 a 5 ar hap
$D$2,$D$3,$D$4,$D$5,$D$6: y rhestr o werthoedd i ddewis ohonynt
Ex5 - Cyfuno CHOOSE ac VLOOKUP swyddogaethau i ddychwelyd gwerth yn y golofn chwith
Yn gyffredinol, rydym yn defnyddio'r swyddogaeth VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) i ddychwelyd gwerth yn seiliedig ar werth penodol o ystod tabl. Ond gyda'r VLOOKUP swyddogaeth, bydd yn dychwelyd gwerth gwall tra bo'r golofn ddychwelyd ar ochr chwith y golofn edrych fel isod y llun a ddangosir:
Yn yr achos hwn, gallwch gyfuno'r CHOOSE swyddogaeth gyda swyddogaeth VLOOKUP i ddatrys y broblem.
Fformiwla:
=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)
Esboniwch:
CHOOSE({1,2},B1:B7,A1:A7): fel dadl table_range yn swyddogaeth VLOOKUP. Mae {1,2} yn golygu arddangos 1 neu 2 fel dadl index_num yn seiliedig ar y ddadl col_num yn swyddogaeth VLOOKUP. Yma, mae'r col_num yn swyddogaeth VLOOKUP yn 2, felly mae'r CHOOSE arddangos swyddogaeth fel CHOOSE(2, B1:B7,A1:A7), yn golygu dewis gwerth o A1: A7.
Ex6 - Dychwelyd yn ystod yr wythnos neu'r mis yn seiliedig ar y dyddiad penodol
Efo'r CHOOSE swyddogaeth, gallwch hefyd ddychwelyd y diwrnod a'r mis cymharol wythnosol yn seiliedig ar ddyddiad penodol.
Fformiwla 1: dychwelyd yn ystod yr wythnos erbyn dyddiad
=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")
Esboniwch:
WEEKDAY(): y ddadl index_num, i gael rhif yn ystod yr wythnos o'r dyddiad a roddir, er enghraifft, WYTHNOS (A5) yn dychwelyd 6, yna dadl y index_num yw 6.
"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": dadleuon rhestr werthoedd, dechreuwch gyda “dydd Sul” oherwydd bod rhif “1” yn ystod yr wythnos yn nodi “dydd Sul”.
Fformiwla 2: mis dychwelyd erbyn dyddiad
=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")
Esboniwch:
MONTH(): dadl index_num, sy'n cael rhif y mis o'r dyddiad penodol, er enghraifft, mae MIS (A5) yn dychwelyd 3.
Ex7 - Dychwelwch i'r dyddiad diwrnod gwaith / penwythnos nesaf yn seiliedig ar heddiw
Mewn gwaith beunyddiol, efallai yr hoffech chi gyfrifo'r diwrnod gwaith neu'r penwythnos nesaf yn seiliedig ar heddiw. Yma mae'r CHOOSE gall swyddogaeth hefyd wneud ffafr i chi.
Er enghraifft, heddiw yw 12/20/2018, dydd Iau, nawr mae angen i chi gael y diwrnod gwaith a'r penwythnos nesaf.
Fformiwla 1: cael y dyddiad heddiw
=TODAY()
Canlyniad: 12/20/2018
Fformiwla 2: cael y rhif yn ystod yr wythnos heddiw
=WEEKDAY(TODAY())
Canlyniad: 5 (tra heddiw yw 12/20/2018)
Dangosir y rhestr rhifau yn ystod yr wythnos fel y llun isod:
Fformiwla 3: cael y diwrnod gwaith nesaf
=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)
Esboniwch:
Today(): dychwelwch y dyddiad cyfredol
WEEKDAY(TODAY()): dadl index_num yn y CHOOSE swyddogaeth, cael y rhif yn ystod yr wythnos heddiw, er enghraifft, dydd Sul yw 1, dydd Llun yw 2…
1,1,1,1,1,3,2: dadl rhestr werth yn y CHOOSE swyddogaeth. Er enghraifft, os yw diwrnod yr wythnos (heddiw ()) yn dychwelyd 1 (dydd Sul), mae'n dewis 1 ffurfio'r rhestr o werthoedd, yna mae'r fformiwla gyfan yn newid i = Heddiw () + 1, sy'n golygu ychwanegu 1 diwrnod i ddychwelyd ddydd Llun nesaf. Os yw diwrnod yr wythnos (heddiw ()) yn dychwelyd 6 (dydd Gwener), mae'n dewis 3 o'r rhestr o werthoedd, oherwydd mae dydd Gwener 3 diwrnod ymhell o ddydd Llun nesaf.
Canlyniad (tra heddiw yw 12/20/2018):
=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)
= 12/20/2018 + 1
= 12/21/2018
Fformiwla 4: cael y diwrnod penwythnos nesaf
=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)
Esboniwch:
6,5,4,3,2,1,1: dadl rhestr werth yn y CHOOSE swyddogaeth. Er enghraifft, os yw diwrnod yr wythnos (heddiw ()) yn dychwelyd 1 (dydd Sul), mae'n dewis 6 o'r rhestr o werthoedd, yna mae'r fformiwla gyfan yn newid i = Heddiw () + 6, sy'n golygu ychwanegu 6 diwrnod a dychwelyd ddydd Sadwrn nesaf.
Canlyniad:
=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)
= 12/20/2018 + 2
= 12/22/2018
Ffeil Sampl
Yr Offer Cynhyrchedd Swyddfa Gorau
Kutools for Excel - Yn Eich Helpu i Sefyll Allan O'r Tyrfa
Kutools for Excel Yn cynnwys dros 300 o nodweddion, Sicrhau mai dim ond clic i ffwrdd yw'r hyn sydd ei angen arnoch chi...
Office Tab - Galluogi Darllen a Golygu Tabiau yn Microsoft Office (gan gynnwys Excel)
- Un eiliad i newid rhwng dwsinau o ddogfennau agored!
- Gostyngwch gannoedd o gliciau llygoden i chi bob dydd, ffarweliwch â llaw llygoden.
- Yn cynyddu eich cynhyrchiant 50% wrth wylio a golygu sawl dogfen.
- Yn dod â Thabiau Effeithlon i'r Swyddfa (gan gynnwys Excel), Just Like Chrome, Edge a Firefox.
