Note: The other languages of the website are Google-translated. Back to English
Mewngofnodi  \/ 
x
or
x
Cofrestru  \/ 
x

or

Excel IF swyddogaeth

Mae'r swyddogaeth IF yn un o'r swyddogaethau symlaf a mwyaf defnyddiol yn llyfr gwaith Excel. Mae'n perfformio prawf rhesymegol syml sy'n dibynnu ar ganlyniad y gymhariaeth, ac mae'n dychwelyd un gwerth os yw'r canlyniad yn WIR, neu werth arall os yw'r canlyniad yn GAU.


 Cystrawen:

Y gystrawen ar gyfer swyddogaeth IF yn Excel yw:

=IF (logical_test, [value_if_true], [value_if_false])

doc os yw swyddogaeth 2


 Dadleuon:

  • logical_test: Angenrheidiol. Dyma'r cyflwr rydych chi am ei brofi.
  • value_if_true: Dewisol. Gwerth penodol yr ydych am ei ddychwelyd os yw'r canlyniad rhesymegol_test yn WIR.
  • value_if_false: Dewisol. Gwerth yr ydych am ei ddychwelyd os yw'r canlyniad rhesymegol_test yn GAU.

Nodiadau:

1. Os gwerth_if_true yn cael ei hepgor:

  • Os yw'r gwerth_if_true hepgorir dadl yn y swyddogaeth IF, fel dim ond coma yn dilyn y logical_test, bydd yn dychwelyd sero pan fydd yr amod wedi'i fodloni. Er enghraifft: =IF(C2>100,, "Low ").
  • Os ydych chi am ddefnyddio cell wag yn lle'r sero os yw'r amod yn cael ei fodloni, dylech nodi dyfynbrisiau dwbl "" yn yr ail baramedr, fel hyn: =IF(C2>100, "", "Low").
doc os yw swyddogaeth 3 doc os yw swyddogaeth 4

2. Os gwerth_if_false yn cael ei hepgor:

  • Os yw'r gwerth_if_false hepgorir paramedr yn y swyddogaeth IF, bydd yn dychwelyd GAU pan na fodlonir yr amod penodedig. Fel: =IF(C2>100, "High").
  • Os rhowch goma ar ôl y ddadl value_if_true, bydd yn dychwelyd sero pan na fodlonir yr amod penodedig. Fel: =IF(C2>100, "High" ,).
  • Os rhowch ddyfynbrisiau dwbl "" yn y trydydd paramedr, bydd cell wag yn dychwelyd os na fodlonir yr amod. Fel: =IF(C2>100, "High" , "").
doc os yw swyddogaeth 5 doc os yw swyddogaeth 6 doc os yw swyddogaeth 7

 Dychwelyd:

Profwch am gyflwr penodol, mae'n dychwelyd y gwerth cyfatebol rydych chi'n ei gyflenwi ar gyfer GWIR neu GAU.


 Enghreifftiau:

Enghraifft 1: Defnyddio swyddogaeth IF syml ar gyfer rhifau

Er enghraifft, mae'n debyg, rydych chi am brofi rhestr o werthoedd, os yw'r gwerth yn fwy na gwerth penodol 100, mae testun “Da” yn cael ei arddangos, os na, dychwelir testun “Drwg”.

Rhowch y fformiwla isod, a byddwch yn cael y canlyniad isod yn ôl yr angen.

=IF(B2>100,"Good","Bad")

doc os yw swyddogaeth 8


Enghraifft 2: Defnyddio swyddogaeth IF ar gyfer gwerthoedd testun

Achos 1: Swyddogaeth OS ar gyfer gwerthoedd testun gydag achos yn ansensitif:

Yma, mae gen i dabl gyda rhestr o Dasgau a Statws Cwblhau, nawr, rydw i eisiau gwybod pa dasgau sydd angen mynd ymlaen, a pha rai sydd ddim. Pan fydd y testun yng Ngholofn C wedi'i gwblhau, bydd “Na” yn cael ei arddangos, fel arall, dychwelir “Ydw”.

Defnyddiwch y fformiwla ganlynol, nawr, bydd y gell yn dychwelyd “Na” pan fydd testun yng ngholofn C yn cael ei arddangos fel “wedi'i gwblhau”, ni waeth ei fod yn uwch neu'n uwch; os dychwelir testun arall yng ngholofn C, “Ydw”. Gweler y screenshot:

=IF(C2="completed", "No", "Yes")

doc os yw swyddogaeth 9

Achos 2: Swyddogaeth OS ar gyfer gwerthoedd testun gyda sensitif i achos:

Er mwyn profi'r gwerthoedd testun â sensitif i achos, dylech gyfuno'r swyddogaeth IF â'r swyddogaeth EXACT, cymhwyswch isod y fformiwla, yna dim ond y testun gyda'r union gyfatebiad a gydnabyddir, a byddwch yn cael y canlyniad isod fel y dymunwch:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc os yw swyddogaeth 10

Achos 3: Swyddogaeth OS ar gyfer gwerthoedd testun gyda chydweddiad rhannol:

Weithiau, mae angen i chi wirio'r gwerthoedd celloedd yn seiliedig ar destun rhannol, yn yr achos hwn, dylech ddefnyddio'r swyddogaethau IF, ISNUMBER a CHWILIO gyda'i gilydd.

Er enghraifft, os ydych chi am wirio'r celloedd sy'n cynnwys y testun “comp”, ac yna dychwelyd y gwerthoedd cyfatebol, defnyddiwch y fformiwla isod. A byddwch yn cael y canlyniad fel y dangosir isod screenshot:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc os yw swyddogaeth 11

Nodiadau:

  • 1. Mae'r swyddogaeth CHWILIO yn cael ei chymhwyso ar gyfer testun ag achos yn ansensitif, os ydych chi am wirio'r testun yn sensitif i achos, dylech ddisodli'r swyddogaeth CHWILIO â swyddogaeth FIND. Fel hyn:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Mae'r testun yn gwerthfawrogi fel paramedrau yn y fformwlâu IF, rhaid i chi eu hamgáu mewn "dyfyniadau dwbl".

Enghraifft 3: Defnyddio swyddogaeth IF ar gyfer gwerthoedd dyddiad

Achos 1: OS swyddogaeth ar gyfer dyddiadau i gymharu dyddiadau â dyddiad penodol:

Os ydych chi am gymharu dyddiadau i wirio a ydyn nhw'n fwy neu'n llai na dyddiad penodol, gall y swyddogaeth IF hefyd ffafrio chi. Gan na all swyddogaeth IF gydnabod fformat dyddiad, dylech gyfuno swyddogaeth DATEVALUE ag ef.

Defnyddiwch y fformiwla hon, pan fydd y dyddiad yn fwy na 4/15/2019, dychwelir “Ydw”, fel arall, bydd y fformiwla yn dychwelyd testun “Na”, gweler y screenshot:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc os yw swyddogaeth 12

Nodyn: Yn y fformiwla uchod, gallwch ddefnyddio'r cyfeirnod celloedd yn uniongyrchol heb ddefnyddio'r swyddogaeth DATEVALUE hefyd. Fel hyn: =IF(D4>$D$1, "Yes", "No").

doc os yw swyddogaeth 13

Achos 2: OS yw'r swyddogaeth ar gyfer dyddiadau i wirio dyddiadau yn fwy neu'n llai na 30 diwrnod:

Os ydych chi am nodi'r dyddiadau sy'n fwy neu'n llai na 30 diwrnod o'r dyddiad cyfredol, gallwch gyfuno'r swyddogaeth HEDDIW â'r swyddogaeth IF.

Rhowch y fformiwla hon:

Nodwch y dyddiad sy'n hŷn na 30 diwrnod: =IF(TODAY()-C4>30,"Older date","")

Nodwch y dyddiad sy'n fwy na 30 diwrnod: =IF(C4-TODAY()>30, "Future date", "")

doc os yw swyddogaeth 14 doc os yw swyddogaeth 15

Nodyn: Os hoffech chi roi'r ddau ganlyniad mewn un golofn, mae angen i chi ddefnyddio swyddogaeth IF wedi'i nythu fel hyn:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc os yw swyddogaeth 16


Enghraifft 4: Defnyddio swyddogaeth IF gyda AND, NEU gweithredu gyda'i gilydd

Mae'n ddefnydd cyffredin i ni gyfuno'r swyddogaethau IF, AND, OR gyda'n gilydd yn Excel.

Achos 1: Defnyddio'r swyddogaeth IF gyda AND swyddogaethau i wirio a yw'r holl amodau'n wir:

Rwyf am wirio a yw'r holl amodau a osodais yn cael eu bodloni, megis: Mae B4 yn Goch, C4 yn Fach a D4> 200. Os yw'r holl amodau yn TURE, marciwch y canlyniad fel “Ydw”; Os yw'r naill amod neu'r llall yn GAU, yna dychwelwch “Na”.

Defnyddiwch y fformiwla hon, a byddwch yn cael y canlyniad fel y dangosir ar-lein:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc os yw swyddogaeth 17

Achos 2: Mae defnyddio'r swyddogaeth IF gyda swyddogaethau OR i wirio unrhyw un o'r amodau yn wir:

Gallwch hefyd ddefnyddio swyddogaethau IF ac OR i wirio a yw unrhyw un o'r amodau yn wir, er enghraifft, rwyf am nodi a yw'r gell yng ngholofn B yn cynnwys y testun “Glas” neu “Coch”, os oes unrhyw destun yng ngholofn B, Arddangosir Ie, fel arall, dychwelir Na.

Yma, dylech gymhwyso'r fformiwla hon, a dangosir y canlyniad isod:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc os yw swyddogaeth 18

Achos 3: Defnyddio'r swyddogaeth IF gyda swyddogaethau AND a OR gyda'i gilydd:

Yr enghraifft hon, byddaf yn cyfuno'r swyddogaeth IF gyda'r ddwy swyddogaeth AND & OR ar yr un pryd. Gan dybio, dylech wirio'r amodau canlynol:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Os bodlonir y naill neu'r llall o'r amodau uchod, dychwelir Gêm, fel arall, Na.

Defnyddiwch y fformiwla hon, a byddwch yn cael y canlyniad isod yn ôl yr angen:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc os yw swyddogaeth 19


Enghraifft 5: Defnyddio swyddogaeth IF Nested

Defnyddir swyddogaeth OS i brofi cyflwr a dychwelyd un gwerth os yw'r amod yn cael ei fodloni a gwerth arall os na chaiff ei fodloni. Ond, weithiau, dylai fod angen i chi wirio mwy nag un cyflwr ar yr un pryd a dychwelyd gwahanol werthoedd, gallwch ddefnyddio Nested IF i ddatrys y swydd hon.

Datganiad IF Nested sy'n cyfuno amodau IF lluosog, mae'n golygu rhoi datganiad IF y tu mewn i ddatganiad IF arall ac ailadrodd y broses honno sawl gwaith.

Y gystrawen ar gyfer swyddogaeth Nested IF yn Excel yw:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

Nodyn: Yn Excel 2007 a fersiynau diweddarach, gallwch nythu hyd at 64 o swyddogaethau IF mewn un fformiwla, ac yn Excel 2003 a fersiynau cynharach, dim ond 7 swyddogaeth IF nythu y gellir eu defnyddio.

Achos 1: Swyddogaeth IF wedi'i nythu i wirio cyflyrau lluosog:

Defnydd clasurol o'r swyddogaeth IF Nested yw neilltuo gradd llythyren ar gyfer pob myfyriwr yn seiliedig ar eu sgorau. Er enghraifft, mae gennych fwrdd gyda myfyrwyr a'u sgoriau arholiad, nawr rydych chi am ddosbarthu'r sgorau gyda'r amodau canlynol:

doc os yw swyddogaeth 20

Defnyddiwch y fformiwla hon, a byddwch yn cael y canlyniad isod, os yw'r sgôr yn fwy neu'n hafal i 90, mae'r radd yn “Ardderchog”, os yw'r sgôr yn fwy neu'n hafal i 80, mae'r radd yn “Dda”, os yw'r sgôr yn fwy neu'n hafal i 60, mae'r radd yn “Ganolig”, fel arall, mae'r radd yn “Wael”.

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc os yw swyddogaeth 21

Esboniad o'r fformiwla uchod:

doc os yw swyddogaeth 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Achos 2: Swyddogaeth IF wedi'i nythu ar gyfer cyfrifo pris yn seiliedig ar faint:

Gellir defnyddio'r swyddogaeth IF Nested hefyd i gyfrifo pris y cynnyrch yn seiliedig ar faint.

Er enghraifft, rydych chi am ddarparu toriad pris i gwsmeriaid yn seiliedig ar faint, mwy o faint maen nhw'n ei brynu, mwy o ostyngiad y byddan nhw'n ei gael fel islaw'r screenshot a ddangosir.

doc os yw swyddogaeth 23

Gan fod cyfanswm y pris yn hafal i faint lluoswch y pris, felly dylech luosi'r maint penodedig â'r gwerth a ddychwelir gan Ifs nythu. Defnyddiwch y fformiwla hon:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc os yw swyddogaeth 24

Nodyn: Gallwch hefyd ddefnyddio'r cyfeiriadau celloedd i ddisodli'r rhifau prisiau statig, pan fydd y data ffynhonnell yn newid, ni ddylai fod angen i chi ddiweddaru'r fformiwla, defnyddiwch y fformiwla hon: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc os yw swyddogaeth 25

Awgrymiadau: Gan ddefnyddio'r swyddogaeth IF i lunio prawf, gallwch ddefnyddio'r gweithredwyr rhesymegol canlynol:

Gweithredwr Ystyr enghraifft Disgrifiad
> Yn fwy na =IF(A1>10, "OK",) Os yw'r nifer yng nghell A1 yn fwy na 10, mae'r fformiwla'n dychwelyd "Iawn"; fel arall dychwelir 0.
< Llai na =IF(A1<10, "OK", "") Os yw'r nifer yng nghell A1 yn llai na 10, mae'r fformiwla'n dychwelyd "Iawn"; fel arall dychwelir cell wag.
>= Yn fwy na neu'n hafal i =IF(A1>=10, "OK", "Bad") Os yw'r nifer yng nghell A1 yn fwy na neu'n hafal i 10, bydd yn dychwelyd "Iawn"; fel arall, arddangosir "Drwg".
<= Llai na neu'n hafal i =IF(A1<=10, "OK", "No") Os yw'r nifer yng nghell A1 yn llai na neu'n hafal i 10, mae'n dychwelyd "Iawn"; fel arall, dychwelir “Na”.
= Yn hafal i =IF(A1=10, "OK", "No") Os yw'r nifer yng nghell A1 yn hafal i 10, mae'n dychwelyd "Iawn"; fel arall mae'n arddangos "Na".
<> Ddim yn hafal i =IF(A1<>10, "No", "OK") Os nad yw'r nifer yng nghell A1 yn hafal i 10, mae'r fformiwla'n dychwelyd "Na"; fel arall - "Iawn".

Yr Offer Cynhyrchedd Swyddfa Gorau

Kutools for Excel - Yn Eich Helpu i Sefyll Allan O Dyrfa

Hoffech chi gwblhau eich gwaith bob dydd yn gyflym ac yn berffaith? Mae Kutools for Excel yn dod â 300 o nodweddion datblygedig pwerus (Cyfuno llyfrau gwaith, swm yn ôl lliw, rhannu cynnwys celloedd, trosi dyddiad, ac ati ...) ac arbed 80% o amser i chi.

  • Wedi'i gynllunio ar gyfer 1500 o senarios gwaith, yn eich helpu i ddatrys problemau Excel 80%.
  • Gostyngwch filoedd o gliciau bysellfwrdd a llygoden bob dydd, lleddfu'ch llygaid a'ch dwylo blinedig.
  • Dewch yn arbenigwr Excel mewn 3 munud. Nid oes angen cofio unrhyw fformiwlâu poenus a chodau VBA mwyach.
  • Treial am ddim diderfyn 30 diwrnod. Gwarant arian yn ôl 60 diwrnod. Uwchraddio a chefnogi am ddim am 2 flynedd.
Rhuban o Excel (gyda Kutools ar gyfer Excel wedi'i osod)

Tab Swyddfa - Galluogi Darllen a Golygu Tabbed yn Microsoft Office (cynnwys Excel)

  • Un eiliad i newid rhwng dwsinau o ddogfennau agored!
  • Gostyngwch gannoedd o gliciau llygoden i chi bob dydd, ffarweliwch â llaw llygoden.
  • Yn cynyddu eich cynhyrchiant 50% wrth wylio a golygu sawl dogfen.
  • Yn Dod â Thabiau Effeithlon i'r Swyddfa (gan gynnwys Excel), Yn union fel Chrome, Firefox, a New Internet Explorer.
Ergyd Sgrin o Excel (gyda Office Tab wedi'i osod)
Say something here...
symbols left.
You are guest
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.