Sut i symud cyfarfodydd a anfonwyd yn awtomatig i ffolder benodol yn Outlook?

Fel rheol, ar ôl anfon yr e-byst neu'r cyfarfodydd, bydd y ddau ohonynt yn y ffolder Eitemau Anfonedig. Felly, bydd y ffolder Eitemau Anfonedig yn eithaf blêr ac yn feichus. Yr erthygl hon, byddaf yn cyflwyno dull ar gyfer symud y cyfarfodydd a anfonir i ffolder arall yn awtomatig ar ôl i'r cyfarfod gael ei anfon allan.

Symudwch y cyfarfodydd a anfonwyd yn awtomatig i ffolder benodol gyda chod VBA

Symudwch y cyfarfodydd a anfonwyd yn awtomatig i ffolder benodol gyda chod VBA

I symud yr holl wahoddiadau cyfarfod a anfonwyd i ffolder arall yn awtomatig, gall y cod canlynol eich helpu chi, gwnewch fel hyn:

1. Daliwch i lawr y ALT + F11 allweddi i agor y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr.

2. Yn y Microsoft Visual Basic ar gyfer Ceisiadau ffenestr, cliciwch ddwywaith SesiwnOutlook oddi wrth y Prosiect1 (VbaProject.OTM) cwarel i agor y modd, ac yna copïo a gludo'r cod canlynol i'r modiwl gwag.

Cod VBA: Symudwch y cyfarfodydd a anfonir yn awtomatig i ffolder benodol

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

symud doc anfon cyfarfod 1

3. Yna, arbed a chau'r ffenestr cod. Nawr, pan anfonir e-bost cyfarfod allan, bydd yn cael ei symud i ffolder newydd o'r enw Cyfarfodydd O dan y Eitemau wedi'u hanfon ffolder yn awtomatig, gweler y screenshot:

symud doc anfon cyfarfod 2