Dilynwch y camau isod i gopïo strwythur ffolder Outlook i'r bwrdd gwaith neu'r archwiliwr ffenestri.

1. Ar y Pane Llywio, cliciwch i dynnu sylw at y ffolder penodedig y byddwch chi'n copïo strwythur ei ffolder, a'i wasgu Alt + F11 allweddi i agor ffenestr Microsoft Visual Basic for Applications.

2. Cliciwch offer > Cyfeiriadau i agor y blwch deialog Cyfeiriadau. Yna yn y blwch deialog gwiriwch y Amser Rhedeg Sgriptio Microsoft opsiwn, a chliciwch ar y OK botwm. Gweler y screenshot:

3. Cliciwch Mewnosod > Modiwlau, a chopïo a gludo islaw cod VBA i mewn i ffenestr y modiwl newydd.

VBA: Copïwch strwythur ffolder Outlook i archwiliwr windows

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Gwasgwch F5 allwedd neu cliciwch y Run botwm i redeg y VBA hwn.

5. Yn y blwch deialog Pori Am Ffolder, dewiswch y ffolder penodedig y byddwch chi'n gosod strwythur y ffolder wedi'i gopïo, a chliciwch ar y OK botwm. Gweler y screenshot:

Nawr ewch i'r ffolder penodedig, fe welwch fod strwythur y ffolder yn cael ei gopïo i'r ddisg galed benodol. Gweler y screenshot:

Nodyn: mae eitemau'r ffolder, fel e-byst, apwyntiadau, tasgau, ac ati hefyd yn cael eu copïo i ffolderau cyfatebol yn y ddisg galed.

Sut i gopïo strwythur ffolder i ffeil ddata pst newydd yn Outlook?